C
C
      SUBROUTINE  INPUT (JUMP1,NSTOP,MARKY,MAXNO)
C
C     -----------------------------------------------------------------
C
C       SUBROUTINE PURPOSE:
C       INPUT OF DATA.
C
C     -----------------------------------------------------------------
C
      INCLUDE 'CMMNW.DAT'
C
C
      IF (JUMP1.EQ.1) THEN
         IF (LMX.LT.1000) THEN
            WRITE (8,1120) LMX
            NSTOP=1
         ENDIF
C
C  ** INPUT OF DATA OF NETWORK STRUCTURE.
C
         READ (9,*,ERR=99) A1,A2,A3,A4,A5,TR,A6,A7,A8,TINC,SPAN,A9,DR,
     .              A11
         NB=A1+0.4
         NFNUM=A2+0.4
         INFLOW=A3+0.4
         NVPN=A4+0.4
         NETW=A5+0.4
         MADJ=A6+0.4
         ITN=A7+0.4
         NTEMP=A8+0.4
         IOUT=A9+0.4
         IF (A9.LT.0.0) IOUT=A9-0.4
         NHM=A11+0.4
         IF (IOUT.LE.(-2)) WRITE (8,1000) NB,NFNUM,INFLOW,NVPN,NETW,TR,
     .                  MADJ,ITN,NTEMP,TINC,SPAN,IOUT,DR,NHM
         IF (NB.LT.0.OR.NFNUM.LT.0.OR.INFLOW.LT.0) THEN
            WRITE (8,1220)
            NSTOP=1
         ENDIF
         IF (TR.LT.(-100.0).OR.TR.GT.150) TR=75.0
         IF (ABS(TR).LT.0.01) TR=75.0
C        ****************************
         DR1=2116/(53.352*(TR+460.0))
         IF (DR.LE.0.03.OR.DR.GE.0.11) THEN
            DR=DR1
         ELSE IF (ABS(DR-DR1)/DR1.GT.0.5) THEN
            WRITE (8,1200)
         ENDIF
         IF (MADJ.LT.10.OR.MADJ.GT.50) MADJ=15
         IF (ITN.LT.10.OR.ITN.GT.50) ITN=15
         IF ((NB+INFLOW).GT.NMX.OR.NB.LE.1) THEN
            WRITE (8,210) NMX,NB,INFLOW
            NSTOP=1
         ENDIF
         IF (NVPN.GE.1) THEN
            NETW=1
            WRITE (8,270)
         ENDIF
         IF (SPAN.LT.0.1) SPAN=5.0
         IF (IOUT.LE.(-2).AND.NHM.LE.0) WRITE (8,1005)
         IF (IOUT.LE.(-2).AND.NHM.GE.1) WRITE (8,1010)
         DO 1 K=1,NB
            IF (NHM.GE.1) THEN
               READ (9,*,ERR=99) A1,A2,A3,A4,R(K),Q(K),A5,LA(K),A(K),
     .               O(K),HA(K),HK(K),CH4V(K),CH4PA(K),TROCK(K),PSI(K)
               NO(K)=A1+0.4
               JS(K)=A2+0.4
               JF(K)=A3+0.4
               NWTYP(K)=A4+0.4
               IF (A4.LT.0.0) NWTYP(K)=A4-0.0
               KF(K)=A5+0.4
               IF (IOUT.LE.(-2)) WRITE (8,1020) NO(K),JS(K),JF(K),R(K),
     .         Q(K),KF(K),LA(K),A(K),O(K),HA(K),HK(K),CH4V(K)
            ELSE
               READ (9,*,ERR=99) A1,A2,A3,A4,R(K),Q(K),A5,LA(K),A(K),
     .                    O(K),HA(K),HK(K),CH4V(K),CH4PA(K),TROCK(K)
               NO(K)=A1+0.4
               JS(K)=A2+0.4
               JF(K)=A3+0.4
               NWTYP(K)=A4+0.4
               IF (A4.LT.0.0) NWTYP(K)=A4-0.4
               KF(K)=A5+0.4
               IF (IOUT.LE.(-2)) WRITE (8,1020) NO(K),JS(K),JF(K),R(K),
     .         Q(K),KF(K),LA(K),A(K),O(K),HA(K),HK(K),CH4V(K)
            ENDIF
            K1=JS(K)
            K2=JF(K)
            IF (NO(K).LE.0.OR.JS(K).LE.0.OR.JF(K).LE.0.OR.KF(K).LT.0.
     .         OR.LA(K).LT.0.0.OR.A(K).LT.0.0.OR.O(K).LT.0.0.OR.HA(K).
     .         LT.0.0.OR.HK(K).LT.0.0.OR.CH4V(K).LT.0.0.OR.TROCK(K).
     .         LT.0.0) THEN
               WRITE (8,1240) K
               NSTOP=1
            ENDIF
            IF (K1.GE.951.OR.K2.GE.951.OR.K1.LE.0.OR.K2.LE.0) THEN
               WRITE (8,1110) NO(K),JS(K),JF(K)
               NSTOP=1
            ENDIF
            MSL(K1)=1
            MSL(K2)=1
            IF (Q(K).LT.1000.0) Q(K)=1000.0
1        CONTINUE
         NJ=0
         DO 2 I=1,1000
            IF (MSL(I).EQ.1) THEN
               NJ=NJ+1
               MSL(I)=0
            ENDIF
2        CONTINUE
         IF (NJ.GT.NMY) WRITE (8,220) NJ,NMY
         DO 3 I=1,NB
            JSB(I)=JS(I)
3        CONTINUE
C
C     NVPN: MARK FOR PRESENCE OF JUNCTION CARDS.
C     NHM: MARK FOR DESIRED CALCULATION WITH WATER EVAPORATION
C          AND CONDENSATION.
C
         IF (NVPN.LE.0) THEN
            IF (NHM.EQ.0) THEN
               WRITE (8,1030)
               DO 4 K =1,NJ
                  READ (9,*,ERR=99) A1,T(K),Z(K),CH4C(K)
                  JNO(K)=A1+0.4
                  IF (IOUT.LE.(-2)) THEN
                     WRITE (8,1040) JNO(K),T(K),Z(K),CH4C(K)
                  ENDIF
4              CONTINUE
            ELSE
               WRITE (8,1035)
               DO 5 K=1,NJ
                  READ (9,*,ERR=99) A1,T(K),Z(K),CH4C(K),HJN(K)
                  JNO(K)=A1+0.4
                  IF (IOUT.LE.(-2)) THEN
                     WRITE (8,1040) JNO(K),T(K),Z(K),CH4C(K),HJN(K)
                  ENDIF
                  IF (T(K).LT.(-100.0).OR.T(K).GT.1500.0) T(K)=75.0
                  IF (ABS(T(K)).LT.0.01) T(K)=75.0
C                 ********************************
                  IF (HJN(K).LT.0.0.OR.HJN(K).GT.100.0) HJN(K)=80.0
                  IF (ABS(HJN(K)).LT.0.01) HJN(K)=80.0
C                 ***********************************
                  TS=T(K)
                  IF (TS.GT.210.0) TS=210.0
                  IF (TS.LE.122.0) THEN
                    PV=-1.0682+0.07946*TS-0.00129*TS*TS+1.26E-5*TS*TS*TS
                  ELSE
                     PV=-33.786+0.97*TS-9.305E-3*TS*TS+3.65E-5*TS*TS*TS
                  ENDIF
                  PRH2O(K)=6.22E-3*PV*HJN(K)/(101.35-PV*HJN(K)/100.)
5              CONTINUE
            ENDIF
         ENDIF
C
C  ** INPUT OF FAN CHARACTERISTICS.
C     NFNUM: NUMBER OF FANS WITH THEIR CHARACTERISTICS.
C
         IF (NFNUM.GT.0) THEN
            IF (NFNUM.GT.IMX) THEN
               WRITE (8,230) NFNUM,IMX
               NSTOP=1
            ENDIF
            DO 10 K=1,NFNUM
               READ (9,*,ERR=99) A1,A2,A3
               NOF(K)=A1+0.4
               MPTS(K)=A2+0.4
               NSWT(K)=A3+0.4
               IF (IOUT.LE.(-2)) WRITE (8,1050) K,NOF(K),MPTS(K)
               DO 6 KP=1,NB
                  IF (NO(KP).EQ.NOF(K)) GO TO 7
6              CONTINUE
               WRITE (8,1230) NOF(K)
7              INDEX=MPTS(K)
               IF (INDEX.LE.1.OR.INDEX.GT.IMY) THEN
                  WRITE (8,240) INDEX,IMY
                  NSTOP=1
               ENDIF
               READ (9,*,ERR=99) (QF(K,I),PF(K,I),I=1,INDEX)
               IF (IOUT.LE.(-2)) THEN
                  WRITE (8,1060)
                  WRITE (8,1070) (QF(K,I)/1000.0,PF(K,I),I=1,INDEX)
               ENDIF
               DO 8 I=1,INDEX-1
                  IF (QF(K,I+1).LE.QF(K,I)) THEN
                     WRITE (8,360) NOF(K)
                     NSTOP=1
                  ENDIF
8              CONTINUE
10          CONTINUE
         READ (9,*,ERR=99) A1
         NPLOT=A1+0.4
         ENDIF
C
C  ** INPUT OF DATA FOR TEMPERATURE PART OF PROGRAM.
C
      ELSE IF (JUMP1.EQ.2) THEN
         READ (9,*,ERR=99) A1,A2,TSTART,TIME,CRITSM,CRITGS,CRITHT,WRNPR,
     .              WRNSM,WRNGS,WRNHT,HSTART,CRITW
         NAV=A1+0.4
         JSTART=A2+0.4
         IF (IOUT.LE.(-2)) THEN
            WRITE (8,1100) NAV,JSTART,TSTART,TIME,CRITSM,CRITGS,CRITHT,
     .                     WRNPR,WRNSM,WRNGS,WRNHT,HSTART,CRITW
         ENDIF
         IF (TIME.LT.0.5) TIME=10.0
         J3=0
         DO 12 I=1,NJ
            IF (JNO(I).EQ.JSTART) J3=1
12       CONTINUE
         IF (J3.EQ.0) THEN
            WRITE (8,330) JSTART
            NSTOP=1
         ENDIF
         IF (TSTART.LT.(-100.0).OR.TSTART.GT.180.0) TSTART=TR
         IF (CRITW.LT.1.0) CRITW=122.0
         IF (NHM.GT.0.AND.MARKY.EQ.0) WRITE (8,260) CRITW
         TS=TSTART
         IF (TS.LE.122.0) THEN
            PV=-1.0682+0.07946*TS-0.00129*TS*TS+1.26E-5*TS*TS*TS
         ELSE
            PV=-33.786+0.97*TS-9.305E-3*TS*TS+3.65E-5*TS*TS*TS
         ENDIF
C
C     HSTART: HUMIDITY RATIO IN THE USER-SPECIFIED STARTING JUNCTION.
C
         HSTART=6.22E-3*PV*HSTART/(101.35-PV*HSTART/100.0)
      ELSE IF (JUMP1.EQ.3) THEN
C
C  ** INPUT OF DATA FOR FIRE SOURCES.
C     INFLOW: NUMBER OF CONTAMINATION CARDS.
C
         IF (INFLOW.GT.0) THEN
            IF (INFLOW.GT.IMX) THEN
               WRITE (8,250) INFLOW,IMX
               NSTOP=1
            ENDIF
            IF ((NB+INFLOW).GT.NMX) THEN
               WRITE (8,340) NB,INFLOW,NMX
               NSTOP=1
            ELSE
               IF (IOUT.LE.(-2).AND.NHM.GE.1) WRITE (8,1080)
               IF (IOUT.LE.(-2).AND.NHM.LE.0) WRITE (8,1085)
               DO 60 I=1,INFLOW
                  IF (NHM.GE.1) THEN
                     READ (9,*,ERR=99) A1,CONT(I),CONC(I),HEAT(I),
     .                     O2MIN(I),SMPO2(I),HTPO2(I),QCENT(I),TPR(I),
     .                     CN(I),HN(I)
                     NCENT(I)=A1+0.4
                     IF (IOUT.LE.(-2)) THEN
                        WRITE (8,1090) NCENT(I),CONT(I),CONC(I),HEAT(I),
     .                     O2MIN(I),SMPO2(I),HTPO2(I),TPR(I),QCENT(I),
     .                     CN(I),HN(I)
                     ENDIF
                     IF (CN(I).LE.1.E-10.OR.HN(I).LT.1.E-10) THEN
                        CN(I)=2.0
                        HN(I)=4.0
                     ENDIF
                  ELSE
                     READ (9,*,ERR=99) A1,CONT(I),CONC(I),HEAT(I),
     .                     O2MIN(I),SMPO2(I),HTPO2(I),QCENT(I),TPR(I)
                     NCENT(I)=A1+0.4
                     IF (IOUT.LE.(-2)) THEN
                        WRITE (8,1090) NCENT(I),CONT(I),CONC(I),HEAT(I),
     .                     O2MIN(I),SMPO2(I),HTPO2(I),TPR(I),QCENT(I)
                     ENDIF
                  ENDIF
                  IF (MAXJ.LT.951) MAXJ=951
                  DO 50 J=1,NB
                     IF (NO(J).EQ.NCENT(I)) THEN
                        IF (NWTYP(J).NE.0) THEN
                           WRITE (8,1250) NCENT(I)
                           NSTOP=1
                        ENDIF
                        IF (TPR(I).LT.1.E-5) TPR(I)=1.E-5
                        IF (QCENT(I).LT.0.0) QCENT(I)=0.0
                        IF (QCENT(I).GT.10.0) THEN
                           VART=(9900.0+TR)**2+2.0*HEAT(I)/
     .                          (QCENT(I)*DR*2.4E-5)
                           IF (VART.LT.9.4E7) THEN
                              WRITE (8,930) NCENT(I)
                              NSTOP=1
                           ENDIF
                           TESTI=-9900.0+SQRT(VART)
                        IF (O2MIN(I).LE.0.1.AND.SMPO2(I).LE.1.E-3.AND.
     .                     HTPO2(I).LT.1.0.AND.MARKY.LE.0) THEN
                           IF (TESTI.LT.(-70.0).OR.TESTI.GT.3000.0)
     .                        WRITE (8,870) NCENT(I)
                        ENDIF
                        ENDIF
                        DO 145 K=1,NJ
                           IF (JS(J).EQ.JNO(K)) GO TO 146
145                     CONTINUE
                        WRITE (8,900) NCENT
                        NCENT(I)=0
                        GO TO 60
146                     DO 155 I2=NB+1,J+1,-1
                           NO(I2)=NO(I2-1)
                           JS(I2)=JS(I2-1)
                           JF(I2)=JF(I2-1)
                           NWTYP(I2)=NWTYP(I2-1)
                           R(I2)=R(I2-1)
                           RSTD(I2)=RSTD(I2-1)
                           Q(I2)=Q(I2-1)
                           KF(I2)=KF(I2-1)
                           LA(I2)=LA(I2-1)
                           A(I2)=A(I2-1)
                           O(I2)=O(I2-1)
                           HA(I2)=HA(I2-1)
                           HK(I2)=HK(I2-1)
                           CH4V(I2)=CH4V(I2-1)
                           CH4PA(I2)=CH4PA(I2-1)
                           TROCK(I2)=TROCK(I2-1)
155                     CONTINUE
                        NO(J+1)=1000+MAXNO+1
                        IF (NO(J+1).GT.9995) NO(J+1)=MAXNO+1
                        JS(J+1)=MAXJ+1
                        JF(J)=MAXJ+1
                        NWTYP(J)=10
                        RSTD(J+1)=R(J+1)
                        R(J)=R(J)*0.01
                        IF (R(J).GT.0.001) R(J)=0.001
                        RSTD(J)=R(J)
                        LA(J+1)=LA(J)
                        LA(J)=0.1
                        CH4V(J)=0.0
                        CH4PA(J)=0.0
                        JNO(NJ+1)=MAXJ+1
                        T(NJ+1)=T(K)
                        Z(NJ+1)=Z(K)
                        CH4C(NJ+1)=CH4C(K)
                        NB=NB+1
                        NJ=NJ+1
                        MAXNO=MAXNO+1
                        MAXJ=MAXJ+1
                        GO TO 60
                     ENDIF
50                CONTINUE
60             CONTINUE
               DO 65 I=1,NB
                  JSB(I)=JS(I)
65             CONTINUE
            ENDIF
         ENDIF
      ENDIF
      RETURN
99    NSTOP=1
      WRITE (6,1210)
      WRITE (8,1210)
      RETURN
C
210   FORMAT (//,1X,'* ERR * NB+INFLOW MUST BE LESS THAN ',I5,' AND ',
     .        'LARGER THAN 1',/,' CURRENT NB= ',I4,'   INFLOW= ',I3)
220   FORMAT (//,1X,'* ERR * NETWORK CONTAINS',I4,' JUNCTIONS',/,
     .        1X,'WHICH IS BEYOND THE CAPACITY OF ARRAYS:',I5)
230   FORMAT (//,1X,'* ERR * NETWORK CONTAINS',I4,' FANS',/,
     .        1X,'WHICH IS BEYOND THE CAPACITY OF ARRAYS:',I4)
240   FORMAT (//,1X,'* ERR * FAN CURVE CONTAINS',I4,' POINTS',/,
     .        1X,'WHICH IS BEYOND THE CAPACITY OF ARRAYS:',I4)
250   FORMAT (//,1X,'*  ERR * NETWORK CONTAINS',I4,' FIRE SOURCES'
     .        ,/,1X,'WHICH IS BEYOND THE CAPACITY OF ARRAYS:',I4)
260   FORMAT (/,1X,'* ATTN * DRY CONDITION ASSUMED WHEN WALL',
     .        ' TEMP. EXCEEDS',F6.0,' DEG. F.',/)
270   FORMAT (//,1X,'NO JUNCTION CARDS ARE EXPECTED TO READ IN',
     .        ' DUE TO NVPN > 0.',/,' ONLY NETWORK PART WILL BE',
     .        ' PERFORMED.')
290   FORMAT (4I5,F10.3,F10.0,5X,I5,F10.0,2F10.1)
310   FORMAT (I5,F10.2,4F10.5)
330   FORMAT (//,1X,'* ERR * START JUNCTION ',I5,' NOT IN JNO LIST.')
340   FORMAT (//,' * ERR * CURRENT INPUT DATA:  NB:',I5,5X,'INFLOW:',
     .        I5,/,' THE SUM OF NB AND INFLOW MUST BE LESS THEN ',I5)
350   FORMAT (//,' * ATTN * A NEW BRANCH HAS BEEN SET UP FOR FIRE ',
     .        'SOURCE',I6,/,' WHICH IS NOW CALLED BRANCH',I6,/)
360   FORMAT (//,' * ERR * FAN CURVE DATA INPUT MUST BE IN THE ORDER',
     .        ' FROM SMALL-QF',/,' TO LARGE-QF, INVALID ORDER DETECTED',
     .        ' FOR FAN ',I5)
870   FORMAT (/,1X,'* WRN *  ABNORMAL TEMPERATURE MAY RESULT IN ',
     .        'BRANCH',I5,/,' ADJUST HEAT AND/OR QCENT.')
880   FORMAT (/,' * ERR *  FUME CONCENTRATION (CONC) HIGHER THAN ',
     .        '100% (CONC=',F5.0,')',/,' FOR FIRE SOURCE',I5)
890   FORMAT (/,1X,'* WRN *  (HTPO2=',F5.0,') FOR FIRE SOURCE',I5,
     .        ' IS UNLIKELY HIGH,',/,' ANOMALOUS CONSEQUENCE MAY ',
     .        'RESULT.')
900   FORMAT (/,1X,' * WRN *  AIRWAY OR STARTING JUNCTION NUMBER ',
     .        'OF HEAT',/,1X,'SOURCE ',I5,' IS NOT ON THE LIST. DATA ',
     .        'IGNORED.')
930   FORMAT (/,1X,'* ERR *  ABNORMAL TEMPERATURE WAS RESULTED IN ',
     .        'AIRWAY ',I5,/,' ADJUST HEAT INPUT AND/OR QCENT.')
1000  FORMAT (//,' * CONTROL DATA LIST *',//,T2,'NB=',T7,I7,T18,'NFNUM='
     .      ,T25,I7,T35,'INFLOW=',T45,I7,T55,'NVPN=',T61,I7,/,T2,'NETW='
     .       ,T7,I7,T18,'TR=',T25,F7.1,T35,'MADJ=',T45,I7,T55,'ITN=',
     .       T61,I7,/,T2,'NTEMP=',T7,I7,T18,'TINC=',T25,F7.1,T35,'SPAN='
     .       ,T45,F7.1,T55,'IOUT=',T61,I7,/,T2,'DR=',T7,F7.4,T18,
     .       'NHM=',T25,I7)
1005  FORMAT (///,' * INPUT DATA LIST (AIRWAY: NWTYP, CH4PA, TROCK NOT',
     .       ' SHOWN) *',//,T3,'NO',T7,'JS',T12,'JF',T18,'R',T26,'Q',
     .       T34,'KF',T40,'LA',T46,'A',T52,'O',T58,'HA',T64,'HK',T69,
     .       'CH4V',/)
1010  FORMAT (///,' * INPUT DATA LIST (AIRWAY: NWTYP, CH4PA, TROCK AND',
     . ' PSI NOT SHOWN) *',//,T3,'NO',T7,'JS',T12,'JF',T18,'R',T26,'Q',
     .       T34,'KF',T40,'LA',T46,'A',T52,'O',T58,'HA',T64,'HK',T69,
     .       'CH4V',/)
1020  FORMAT (T2,I4,T6,I4,T10,I4,T15,F7.2,T23,F7.0,T32,I4,T37,F6.0,
     .       T44,F5.1,T50,F5.1,T56,F5.1,T62,F5.1,T68,F5.1)
1030  FORMAT (///,' * INPUT DATA LIST (JUNCTION DATA) *',//,
     .            T3,'JNO',T16,'T',T28,'Z',T40,'CH4C',/)
1040  FORMAT (T2,I5,T12,F7.1,T23,F8.1,T38,F6.2,T51,F6.2)
1035  FORMAT (///,' * INPUT DATA LIST (JUNCTION DATA) *',//,
     .            T3,'JNO',T16,'T',T28,'Z',T40,'CH4C',T53,'HJN',/)
1050  FORMAT (///,' * INPUT DATA LIST (FAN CURVE DATA) *',//,
     .           T5,'FAN ',I3,':   NOF=',I5,'    MPTS=',I5,/)
1060  FORMAT (/,5('  Q*1000   PF '),/)
1070  FORMAT (5(F8.2,F6.2)/,5(F8.2,F6.2),/)
1080  FORMAT (///,' * INPUT DATA LIST (HEAT SOURCE DATA) *',//,
     .           T2,'NCENT',T8,'CONT',T14,'CONC',T21,'HEAT',T28,'O2MIN',
     .       T35,'SMPO2',T41,'HTPO2',T49,'TPR',T56,'QCENT',T64,'CN',T70,
     .       'HN',/)
1085  FORMAT (///,' * INPUT DATA LIST (HEAT SOURCE DATA) *',//,
     .           T2,'NCENT',T8,'CONT',T14,'CONC',T21,'HEAT',T28,'O2MIN',
     .       T35,'SMPO2',T41,'HTPO2',T49,'TPR',T56,'QCENT',/)
1090  FORMAT (T2,I4,T6,F6.0,T12,F6.2,T18,F8.0,T28,F5.2,T34,F6.1,T40,F6.1
     .       ,T46,F6.2,T53,F8.0,T62,F5.2,T68,F5.2)
1100  FORMAT (///,' * INPUT DATA LIST (CONTROL DATA II) *',//,
     .           T2,'NAV=',T8,I7,T18,'JSTART=',T26,I7,T37,'TSTART=',T45,
     .       F7.2,T56,'TIME=',T63,F7.2,/,T2,'CRITSM=',T8,F7.2,T18,
     .       'CRITGS=',T26,F7.2,T37,'CRITHT=',T45,F7.2,T56,'WRNPR=',T63,
     .       F7.2,/,T2,'WRNSM=',T8,F7.2,T18,'WRNGS=',T26,F7.2,T37,
     .       'WRNHT=',T45,F7.2,T56,'HSTART=',T63,F7.2,/,T2,'CRITW=',
     .       T8,F7.2,/)
1110  FORMAT (/,' * ERR * JUNCTION ID MUST BE WITHIN 1 AND 950.',/,
     .       ' CURRENT INPUT:  NO=',I5,'  JS=',I5,'  JF=',I5)
1120  FORMAT (/,' * ERR * PARAMETER LMX MUST BE 1000 OR LARGER.')
1200  FORMAT (/,' * ATTN * REF. DENSITY MUST MATCH REF. TEMPERATURE ',
     .        'AND ATM. PRESSURE.',/)
1210  FORMAT (//,' * ERR * ERROR READING INPUT DATA.',/)
1220  FORMAT (/,' * ERR * INVALID NEGATIVE INPUT DETECTED IN CONTROL ',
     .        'DATA LINE I.')
1230  FORMAT (/,' * ATTN * FAN ',I5,' IS ISOLATED FROM THE NETWORK.')
1240  FORMAT (/,' * ERR * INVALID NEGATIVE INPUT DETECTED FOR AIRWAY ',
     .        'DATA GROUP LINE ',I4)
1250  FORMAT (/,' * ERR * A HEAT SOURCE MUST IN AN ORDINARY AIRWAY ',
     .        '(NWTYP=0).')
C
      END

